Inhalte

# Kategorie Information

Diese Kategorie enthält die Funktionen zu Information.

So greifen Sie auf diesen Befehl zu:

Einfügen – Funktion… – Kategorie: Informationen

Die Daten in der folgenden Tabelle dienen als Grundlage für einige der Beispiele in den Funktionsbeschreibungen:

| C | D
2 | x-Wert | y-Wert
3 | -5 | -3
4 | -2 | 0
5 | -1 | 1
6 | 0 | 3
7 | 2 | 4
8 | 4 | 6
9 | 6 | 8

## AKTUELL

Diese Funktion gibt das aktuelle Auswertungsergebnis der Formel zurück, von der sie ein Teil ist (mit anderen Worten: das Ergebnis hängt vom Auswertungsgrad ab). Die Funktion wird hauptsächlich in Verbindung mit der Funktion VORLAGE() verwendet, um ausgewählte Vorlagen in Abhängigkeit vom Zellinhalt auf eine Zelle anzuwenden.

#### Syntax

AKTUELL()

#### Beispiel

=1+2+AKTUELL()

Das Beispiel ergibt 6. Die Formel wird von links nach rechts wie folgt berechnet: 1 + 2 = 3, woraus sich das aktuelle Ergebnis ergibt, wenn AKTUELL() gefunden wird; AKTUELL() ergibt folglich 3, dieser Wert wird zum ursprünglichen Wert 3 hinzuaddiert, woraus sich 6 ergibt.

=A2+B2+VORLAGE(WENN(AKTUELL()>10;"Rot";"Standard"))

Das Beispiel ergibt A2 + B2 (VORLAGE ergibt 0). Wenn diese Summe größer als 10 ist, wird die Vorlage Rot auf die Zelle angewandt. Weitere Erläuterungen finden Sie unter Funktion VORLAGE.

="choo"&AKTUELL()

Das Beispiel ergibt choochoo.

#### Technische Information

Diese Funktion ist NICHT Bestandteil des Standards Open Document-Format für Office-Anwendungen (OpenDocument) Version 1.3. Teil 4: Format für neu berechnete Formeln (OpenFormula). Der Namensraum ist

ORG.OPENOFFICE.CURRENT

## FORMEL

Zeigt die Formel einer Formelzelle als eine Textfolge an.

Diese Funktion wird immer neu berechnet, wenn eine Neuberechnung erfolgt.

#### Syntax

FORMEL(Bezug)

Bezug ist ein Bezug auf eine Zelle, die eine Formel enthält.

Ein ungültiger Bezug oder ein Bezug auf eine Zelle, in der keine Formel enthalten ist, führt zu dem Fehlerwert #NV.

#### Beispiel

Wenn Zelle A8 die Formel =SUMME(1;2;3) enthält, dann gibt

=FORMEL(A8) den Text =SUMME(1;2;3) zurück.

## INFO

Gibt spezifische Informationen über die aktuelle Arbeitsumgebung wieder. Die Funktion erwartet ein Textargument und gibt diesem Parameter entsprechend Daten zurück.

Diese Funktion wird immer neu berechnet, wenn eine Neuberechnung erfolgt.

#### Syntax

INFO("Typ")

Die folgende Tabelle enthält eine Liste der Werte für den Textparameter Typ und die Rückgabewerte der Funktion INFO.

Wert für "Typ" | Rückgabewert
--- | ---
"osversion" | Immer "Windows (32-bit) NT 5.01", aus Kompatibilitätsgründen

"system"

Der Typ des Betriebssystems:
"ANDROID" für das mobile Google-Betriebssystem
"DRAGONFLY" für das von FreeBSD abgeleitete DragonFly-Betriebssystem
"EMSCRIPTEN" für das Browser-WebAssembly-System
"FREEBSD", "OPENBSD" oder "NETBSD" für Betriebssysteme, die auf der Berkeley Software Distribution (BSD) basieren
"HAIKU" für das BeOS-kompatible Betriebssystem
"iOS" für das mobile Apple-Betriebssystem
"LINUX" für GNU/Linux-basierte Betriebssysteme
"MACOSX" für Apple macOS
"SOLARIS" für das Oracle Solaris-Betriebssystem
"WNT" für Microsoft Windows

"release" | Die Versionsnummer, zum Beispiel "300m25(Build:9876)"
"numfile" | Immer 1, aus Kompatibilitätsgründen
"recalc" | Aktueller Formelneuberechnungsmodus, entweder "Automatisch" oder "Manuell" (lokalisiert in LibreOffice -Sprache)

Andere Tabellenkalkulationen akzeptieren möglicherweise lokalisierte Werte für den Parameter Typ, LibreOffice Calc akzeptiert jedoch nur die englischen Werte.

#### Beispiel

=INFO("release") ergibt die Releasenummer der verwendeten LibreOffice Version.

=INFO(D5) mit der Zelle D5, die den Text system enthält, ergibt den Typ des Betriebssystems.

## ISTBEZUG

Prüft, ob das Argument ein Bezug ist. Ergibt WAHR, wenn das Argument ein Bezug ist, sonst ergibt es FALSCH. Wenn es ein Bezug ist, gibt die Funktion nicht den referenzierten Wert zurück.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

#### Syntax

ISTBEZUG(Wert)

Wert ist der Wert, der darauf geprüft wird, ob er einen Bezug darstellt.

#### Beispiel

=ISTBEZUG(C5) ergibt das Ergebnis WAHR, weil C5 ein gültiger Bezug ist.

=ISTBEZUG("abcdef") ergibt immer FALSCH, weil ein Text nie ein Bezug sein kann.

=ISTBEZUG(4) ergibt FALSCH.

=ISTBEZUG(INDIREKT("A6")) ergibt WAHR, weil INDIREKT eine Funktion ist, die einen Bezug ergibt.

=ISTBEZUG(ADRESSE(1; 1; 2;"Tabelle2")) ergibt FALSCH, weil ADDRESS eine Funktion ist, die einen Text ergibt, obwohl dieser wie ein Bezug aussieht.

## ISTFEHL

Prüft auf Fehlerbedingungen, außer dem Fehlerwert #NV, und ergibt WAHR oder FALSCH.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

#### Syntax

ISTFEHL(Wert)

Wert ist ein beliebiger Wert oder Ausdruck, der auf einen Fehlerwert ungleich #NV geprüft wird.

#### Beispiel

=ISTFEHL(C8), wobei Zelle C8 =1/0 enthält, ergibt WAHR, weil 1/0 ein Fehler ist.

=ISTFEHL(C9), wobei Zelle C9 =NV() enthält, ergibt FALSCH, weil ISTFEHL() den Fehler #NV ignoriert.

## ISTFEHLER

Prüft auf Fehlerbedingungen, einschließlich dem Fehlerwert #NV, und ergibt WAHR oder FALSCH.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

#### Syntax

ISTFEHLER(Wert)

Wert ist oder bezieht sich auf den zu prüfenden Wert. ISTFEHLER() ergibt WAHR, wenn eine Fehler vorliegt, und FALSCH, wenn kein Fehler vorliegt.

#### Beispiel

=ISTFEHLER(C8), wobei Zelle C8 =1/0 enthält, ergibt WAHR, weil 1/0 ein Fehler ist.

=ISTFEHLER(C9), wobei Zelle C9 =NV() enthält, ergibt WAHR.

## ISTFORMEL

Ergibt WAHR, wenn eine Zelle eine Formel enthält.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

#### Syntax

ISTFORMEL(Bezug)

Bezug gibt den Bezug auf eine Zelle an, in der zu überprüfen ist, ob sie eine Formel enthält.

#### Beispiel

=ISTFORMEL(C4) ergibt FALSCH, wenn Zelle C4 die Zahl 5 enthält.

## ISTGERADE

Ergibt WAHR, falls Wert eine gerade Zahl ist, oder FALSCH, falls Wert ungerade ist.

#### Syntax

ISTGERADE(Wert)

Wert ist der zu prüfende Wert.

Falls Wert keine ganze Zahl ist, werden alle Stellen nach dem Dezimaltrennzeichen ignoriert. Das Vorzeichen von Wert wird ebenfalls ignoriert.

#### Beispiel

=ISTGERADE(48) ergibt WAHR

=ISTGERADE(33) ergibt FALSCH

=ISTGERADE(0) ergibt WAHR

=ISTGERADE(-2,1) ergibt WAHR

=ISTGERADE(3,999) ergibt FALSCH

## ISTGERADE_ADD

Test für gerade Zahlen. Ergibt 1, wenn eine durch 2 geteilte Zahl eine ganze Zahl ergibt.

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.

#### Syntax

ISTGERADE_ADD(Zahl)

Zahl ist die zu prüfende Zahl.

#### Beispiel

=ISTGERADE_ADD(5) ergibt 0.

=ISTGERADE_ADD(A1) ergibt 1, wenn Zelle A1 die Zahl 2 enthält.

## ISTKEINTEXT

Prüft, ob es sich beim Zellinhalt um Text oder Zahlen handelt, und ergibt FALSCH, wenn der Inhalt Text ist.

Wenn ein Fehler auftritt, ergibt die Funktion WAHR.

#### Syntax

ISTKEINTEXT(Wert)

Wert ist ein Wert oder ein Ausdruck, bei dem zu prüfen ist, ob es sich um einen Text oder um Zahlen beziehungsweise einen Wahrheitswert handelt.

#### Beispiel

=ISTKEINTEXT(D2) ergibt FALSCH, wenn Zelle D2 den Text abcdef enthält.

=ISTKEINTEXT(D9) ergibt WAHR, wenn Zelle D9 die Zahl 8 enthält.

## ISTLEER

Ergibt WAHR, wenn der Wert ein Bezug zu einer leeren Zelle ist. Diese Funktion ermittelt, ob eine Zelle leer ist. Eine Zelle, die eine Formel enthält, ist nicht leer.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

#### Syntax

ISTLEER(Wert)

Wert ist der Bezug auf die zu prüfende Zelle.

#### Beispiel

=ISTLEER(D2) ergibt FALSCH.

## ISTLOGISCH

Prüft auf einen logischen Wert (WAHR oder FALSCH).

Wenn ein Fehler auftritt, ergibt die Funktion FALSCH.

#### Syntax

ISTLOGISCH(Wert)

Ergibt WAHR, wenn Wert ein boolescher Wert (WAHR oder FALSCH) ist, und anderenfalls FALSCH.

#### Beispiel

=ISTLOGISCH(99) ergibt FALSCH, weil 99 eine Zahl und kein boolescher Wert ist.

=ISTLOGISCH(ISTNV(D4)) ergibt unabhängig vom Inhalt der Zelle D4 WAHR, weil ISTNV() einen logischen Wert ergibt.

## ISTNV

Ergibt WAHR, wenn eine Zelle den Fehlerwert #NV (Wert nicht verfügbar) enthält.

Wenn ein Fehler auftritt, ergibt die Funktion FALSCH.

#### Syntax

ISTNV(Wert)

Wert ist der Wert oder ein Ausdruck, der zu prüfen ist.

#### Beispiel

=ISTNV(D3) ergibt FALSCH.

## ISTTEXT

Ergibt WAHR, wenn der Zellinhalt auf Text verweist.

Wenn ein Fehler auftritt, ergibt die Funktion FALSCH.

#### Syntax

ISTTEXT(Wert)

Wert ist ein Wert, eine Zahl, ein Wahrheits- oder Fehlerwert, bei denen überprüft wird, ob es sich um einen Text oder um Zahlen handelt.

#### Beispiel

=ISTTEXT(D9) ergibt WAHR, wenn Zelle D9 den Text abcdef enthält.

=ISTTEXT(C3) ergibt FALSCH, wenn Zelle C3 die Zahl 3 enthält.

## ISTUNGERADE

Ergibt WAHR, wenn Wert eine ungerade Zahl ist, oder FALSCH, wenn er gerade ist.

#### Syntax

ISTUNGERADE(Wert)

Wert ist der zu prüfende Wert.

Falls Wert keine ganze Zahl ist, werden alle Stellen nach dem Dezimaltrennzeichen ignoriert. Das Vorzeichen von Wert wird ebenfalls ignoriert.

#### Beispiel

=ISTUNGERADE(33) ergibt WAHR

=ISTUNGERADE(48) ergibt FALSCH

=ISTUNGERADE(3,999) ergibt WAHR

=ISTUNGERADE(-3,1) ergibt WAHR

## ISTUNGERADE_ADD

Ergibt WAHR (1), wenn die Zahl durch 2 dividiert keine ganze Zahl ist.

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.

#### Syntax

ISTUNGERADE_ADD(Zahl)

Zahl ist die zu prüfende Zahl.

#### Beispiel

=ISTUNGERADE_ADD(5) ergibt 1.

## ISTZAHL

Diese Funktion ergibt WAHR, wenn Wert auf eine Zahl verweist.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

#### Syntax

ISTZAHL(Wert)

Wert ist ein beliebiger Ausdruck, der darauf geprüft wird, ob er eine Zahl oder Text darstellt.

#### Beispiel

=ISTZAHL(C3) ergibt WAHR, wenn die Zelle C3 die Zahl 4 enthält.

=ISTZAHL(C2) ergibt FALSCH, wenn Zelle D2 den Text abcdef enthält.

## N

Ergibt den numerischen Wert des gegebenen Parameters. Ergibt 0, wenn der Parameter Text oder FALSCH ist.

Wenn ein Fehler vorliegt, ergibt die Funktion den Fehlercode.

#### Syntax

N(Wert)

Wert ist der Parameter, der in eine Zahl umgewandelt werden soll. N() ergibt den numerischen Wert, falls möglich. Es ergibt 1 und 0 für die logischen Werte WAHR und FALSCH. Bei Text ergibt sie 0.

#### Beispiel

=N(123) ergibt 123

=N(WAHR()) ergibt 1

=N(FALSCH()) ergibt 0

=N("abc") ergibt 0

=N(1/0) ergibt #DIV/0!

## NV

Ergibt den Fehlerwert #NV.

#### Syntax

NV()

#### Beispiel

=NV() wandelt den Inhalt der Zelle in #NV um.

## TYP

Ergibt den Typ von Werte, wobei 1 = Zahl, 2 = Text, 4 = boolescher Wert, 8 = Formel, 16 = Fehlerwert, 64 = Matrix bedeutet.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

#### Syntax

TYP(Wert)

Wert ist der spezifische Wert, dessen Datentyp ermittelt wird.

### Beispiel (siehe Beispieltabelle oben)

=TYP(C2) ergibt 2.

=TYP(D9) ergibt 1.

## WENNFEHLER

Gibt den Wert zurück, wenn die Zelle keinen Fehlerwert enthält, oder den alternativen Wert, wenn sie einen Fehlerwert enthält.

Diese Funktion ist seit LibreOffice 4.0 verfügbar.

#### Syntax

WENNFEHLER(Wert; Alternativer Wert)

Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn er ungleich ist oder zu einem Fehler führt.

Alternativer Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn der Ausdruck oder Wert für Wert gleich ist oder zu einem Fehler führt.

#### Beispiel

WENNFEHLER(C8;C9), wobei C8 =1/0 enthält, ergibt den Wert aus C9, da 1/0 nicht berechnet werden kann.

WENNFEHLER(C8;C9), wobei C8 13 enthält, ergibt 13, den Wert von C8, da 13 kein Fehler ist.

## WENNNV

Gibt den Wert zurück, sofern die Zelle nicht den Fehlerwert #NV (Wert nicht verfügbar) enthält, oder den alternativen Wert, wenn sie den Fehlerwert enthält.

Diese Funktion ist seit LibreOffice 4.0 verfügbar.

#### Syntax

WENNNV(Wert; Alternativer Wert)

Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn er ungleich ist oder zum Fehlerwert #NV führt.

Alternativer Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn der Ausdruck oder Wert von Wert gleich ist oder zum Fehlerwert #NV führt.

#### Beispiel

WENNNV(D3;D4) ergibt den Wert von D3, wenn D3 nicht zum Fehlerwert #NV führt, oder D4, wenn er dies tut.

## ZELLE

Ergibt Informationen zu Adresse, Formatierung oder Inhalt einer Zelle.

#### Syntax

ZELLE("InfoTyp" [; Bezug])

InfoTyp ist die Zeichenfolge, die den Informationstyp festlegt. Die Zeichenfolge ist immer in Englisch angegeben. Die Groß- und Kleinschreibung ist optional.

InfoTyp | Bedeutung
--- | ---
COL | Ergibt die Nummer der referenzierten Spalte. =ZELLE("COL";D2) ergibt 4.
ROW | Ergibt die Nummer der referenzierten Zeile. =ZELLE("ROW";D2) ergibt 2.
SHEET | Ergibt die Nummer der referenzierten Tabelle. =ZELLE("Sheet";Tabelle3.D2) ergibt 3.
ADDRESS | Ergibt die absolute Adresse der referenzierten Zelle. =ZELLE("ADDRESS";D2) ergibt $D$2. =ZELLE("ADDRESS";Tabelle3.D2) ergibt $Tabelle3.$D$2. =ZELLE("ADDRESS";'X:\dr\test.ods'#$Tabelle1.D2) ergibt 'file:///X:/dr/test.ods'#$Tabelle1.$D$2.
FILENAME | Ergibt Dateiname und Tabellennummer der referenzierten Zelle. =ZELLE("FILENAME";D2) ergibt 'file:///X:/dr/own.ods'#$Tabelle1, wenn die Formel im aktuellen Dokument X:\dr\own.ods in Tabelle1 enthalten ist. =ZELLE("FILENAME";'X:\dr\test.ods'#$Tabelle1.D2) ergibt 'file:///X:/dr/test.ods'#$Tabelle1.
COORD | Gibt die vollständige Zelladresse in der Lotus™-Schreibweise aus. =ZELLE("COORD";D2) ergibt $A:$D$2. =ZELLE("COORD"; Tabelle3.D2) ergibt $C:$D$2.
CONTENTS | Ergibt den Inhalt der referenzierten Zelle, ohne jede Formatierung.
TYPE | Ergibt den Typ des Zellinhalts. b = blank. leere Zelle l = label. Text, Ergebnis einer Formel als Text v = value. Wert, Ergebnis einer Formel als Zahl
WIDTH | Ergibt die Breite der referenzierten Spalte. Die Maßeinheit ist die Anzahl der Nullen (0), die in die Spalte passen, in der Standardschrift mit Standardgröße.
PREFIX | Ergibt die Ausrichtung der referenzierten Zelle. ' = linksbündig oder Blocksatz " = rechtsbündig ^ = zentriert \ = wiederholend (zur Zeit inaktiv)
PROTECT | Ergibt den Status des Zellschutzes der Zelle. 1 = Zelle ist geschützt 0 = Zelle ist nicht geschützt

FORMAT

Ergibt eine Zeichenfolge, die das Zahlenformat angibt.

, = Zahl mit Tausendertrennzeichen

F = Zahl ohne Tausendertrennzeichen

C = Währungsformat

S = Exponentialdarstellung, beispielsweise 1,234+E56

P = Prozentzahl

In den obigen Formaten wird die Anzahl der Nachkommastellen als eine Zahl zurückgegeben. Beispiel: Das Zahlenformat #.##0,0 ergibt ,1 und das Zahlenformat 00,000 % ergibt P3

D1 = D-MMM-YY, D-MM-YY und ähnliche Formate

D2 = DD-MM

D3 = MM-YY

D4 = DD-MM-YYYY HH:MM:SS

D5 = MM-DD

D6 = HH:MM:SS AM/PM

D7 = HH:MM AM/PM

D8 = HH:MM:SS

D9 = HH:MM

G = Alle anderen Formate

- (Minus) am Ende = negative Zahlen werden farbig formatiert

() (Klammernpaar) am Ende = es kommt eine öffnende Klammer im Format-Code vor

COLOR | Ergibt 1, wenn negative Werte farbig formatiert sind, sonst 0.
PARENTHESES | Ergibt 1, wenn im Format-Code eine öffnende Klammer ( enthalten ist, sonst 0.

Bezug (optional) ist die Position der zu untersuchenden Zelle. Ist Bezug ein Bereich, gilt die Zelle oben links im Bereich. Fehlt Bezug, nutzt LibreOffice Calc die Position der Zelle, in der diese Formel steht. Microsoft Excel nutzt dann den Bezug zu der Zelle, in der der Cursor steht.

Verwandte Themen

Funktionen nach Kategorie